目录
1.绪论.................................................... 1
1．1 选题的目的和意义.............................................. 1
1．2 课题研究的内容................................................ 1
1．3 课题的优点及组成.............................................. 2
1．4方案论证...................................................... 2
1．5国内外现状.................................................... 3
1．6抢答器的简介.................................................. 3
1．7 抢答器的工作流程.............................................. 5
2.硬件设计................................................ 6
2．1 硬件电路的设计原理............................................ 6
2．2 硬件电路的设计................................................ 6
2．3 最小系统..................................................... 8
2．4 稳压电源电路设计.............................................. 8
2．5 时钟频率电路的设计............................................ 9
2．6 复位电路的设计............................................... 10
2．7 显示电路的设计............................................... 10
2．8 键盘扫描电路的设计........................................... 11
2．9 发声电路的设计............................................... 13
3．软件设计模块........................................... 14
3．1 主程序系统结构图............................................. 14
3．2 软件任务分析................................................ 15
3．3 程序流程图.................................................. 15
3．4 程序清单.................................................... 16
4．系统的调试............................................. 28
结束语................................................... 31
致谢..................................................... 32
参考文献................................................. 33
附录一 元器件清单......................................... 34
附录二 系统原理图......................................... 35
1.绪论
随着计算机技术的发展和在控制系统中的广泛应用，以及设备向小型化、智能化发展，作为高新技术之一的单片机以其体积小、功能强、价格低廉、使用灵活等优势，显示出了很强的生命力。进入21世纪以来，开发推出单片机的公司很多，各种高性能单片机芯片市场也异常活跃，新技术的不断采用，更加使单片机的种类、性能以及应用领域不断扩大和提高。因其功耗低，超高型，低成本，功能完整，在国内越来越受到用户的重视和广泛使用。
1．1 选题的目的和意义
通过这次设计，掌握51单片机的原理，了解简单多功能抢答器组成原理，初步掌握多功能抢答器的调整及测试方法，提高独立思考能力和排除故障的能力。同时通过本课题设计与调试，提高自己的动手能力，巩固已学的理论知识，建立单片机理论和实践的结合，了解多功能抢答器各单元电路之间的关系及相互影响，从而能正确设计、计算定时计数的各个单元电路。初步掌握多功能抢答器的调整及测试方法。无论是学校还是电视节目中,都可能会举办各种各样的智力竞赛,都会用到抢答器。如果要是让抢答者用举手等方法，主持人很容易误判，会造成抢答的不公平，比赛中为了准确、公正、直观地判断出第一抢答者，所设计的抢答器通常由数码显示、灯光、音响等多种手段指示出第一抢答者。为了使这种不公平不发生，只有靠电子产品的高准确性来保障抢答的公平性。
1．2 课题研究的内容
系统采用模块化设计智能抢答器，在抢答比赛中广泛应用，各组分别有一个抢答按钮。主持人有开始和结束、复位键。在后台主持人可以修改，抢答时间和选手回答问题的时间设置，主持人按键开始后，选手开始抢答为有效，数码显示屏显示抢答时间倒计时和选手号，在最后五秒扬声器发生提示。如果主持人没有按下开始键而选手就抢答视为犯规，数码显示屏显示犯规者的代号，扬声器持续发生。主持人可按键结束，新一轮抢答开始。
1．在抢答中，只有开始后抢答才有效，如果在开始抢答前抢答为无效。
2．抢答限定时间和回答问题的时间可以在1～99s设定。
3．可以显示是哪位选手有效抢答和无效抢答，正确按键后有扬声器提示。
4．抢答时间和回答问题时间倒记时显示，时间完后系统自动复位。
5．回答限定时间内使用锦囊回答时间将加到60s。
6．按键锁定，在有效状态下，按键无效非法。
1．3 课题的优点及组成
在知识比赛中，特别是做抢答题目的时候，在抢答过程中，为了知道哪一组或哪一位选手先答题，必须要设计一个系统来完成这个任务。如果在抢答中，靠视觉是很难判断出哪组先答题。利用单片机系统来设计抢答器，使以上问题得以解决，即使两组的抢答时间相差几微秒，也可分辨出哪组优先答题。课题中主要介绍了单片机抢答器设计及工作原理，以及它的实际用途。本系统采用AT89S51单片机作为核心。控制系统的四个模块分别为：存储模块、显示模块、声音模块、抢答开关模块。该抢答器系统通过八个个按键输入抢答信号；利用4个七段共阳数码管来完成显示功能。工作时，用按键通过开关电路输入各路的抢答信号，经单片机的处理，输出控制信号，控制4个七段共阳数码管和喇叭工作。在数码管上显示哪一组先答题，从而实现整个抢答过程。
1．4方案论证
方案一: 八路抢答器可以利用硬件电子元器件实现，系统各部分采用中小规模集成数字电路，用机械开关按钮作为控制开关，完成抢答输入信号的触发。该方案的特点是中小规模集成电路应用技术成熟，性能可靠，能方便地完成选手抢答的基本功能，但是电路结构复杂，调试困难，涉及到外围元件多，并且制作过程工序比较烦琐，不便于安装，实验给实际操作带来很大的麻烦。
方案二: 该系统采用MCS-51系列单片机AT89S51作为控制核心，其片内带有4KflashROM，128的RAM，以及15根I/O口线能满足设计要求。该系统可以完成运算控制、信号识别以及显示功能的实现。利用单片机程序判断选手按键是否有效，但是选手违规抢答，利用简答程序显示，启动扬声器报警，告诉主持人有人违规操作，抢答无效。给出相应的延时，选手按正常的操作抢答，软件倒计时，利用AT89S51移位寄存7段数码管，实现倒计时显示时间，到5秒相应时间提醒选手时间快到了，要及时作答，并启动扬声器。由于用了单片机，使其技术比较成熟，应用起来方便、简单并且单片机周围的辅助电路也比较少，便于控制和实现。整个系统具有极其灵活的可编程性，能方便地对系统进行功能的扩张和更改性。
方案比较分析：从第一个方案我们可以看出，这个抢答器是由抢答电路，定时电路，报警电路，时序控制电路四个电路组成。扩展电路是由秒钟脉冲信号产生电路，译码电路，显示电路等，它的功能很齐全，设计的电路也很稳定。但是它的造价却很高，仅仅是集成电路他就用了八个，这个跟我们当初的设计理念是相冲突的。我们要的是功能齐全，但是造价比较低的设计。所以我们放弃这个方案。而方案二采用单片机，可靠性好，结构简单，具有显示出台号，倒计时功能等。该模式充分体现了原有系统性能的改进，功能的扩展及其他同类系统的不同之处，它包括硬件逻辑图与软件流程图，比较经济实用，所以我们选用单片机的方案。
1．5国内外现状
抢答器作为一种电子产品，早已广泛应用于各种智力和知识竞赛场合，但目前所使用的抢答器有的电路较复杂不便于制作，可靠性低，实现起来很困难；有的则用一些专用的集成块，而专用集成块的购买又很困难。为适应高校等多代表队单位活动的需要而设计一个多功能抢答器，这种抢答器具有电路简单，元件普通，易于购买等优点，很好地解决了制作者制作困难和难于购买的问题。在国内外已经开始了普遍的应用。
1．6抢答器的简介
数字抢答器系统设计是借用单片机采用模块化设计的八路抢答器，包括8路抢答按纽、计时显示、提示功能、开始与结束控制按钮、时限设定、各种相关显示调控功能等。
参赛者系统，除享有抢答按纽的权利功能外，还有人性化的提示功能和时间提示功能，也可设定由主控控制在参赛者终端表现的趣味性功能等；主控系统的控制按钮做开始与结束控制，根据活动参赛者的层次，对提前抡答者的行为设定为非法或阻隔，若设有非法抢答控制功能时，在主控处带有公示性显示的非法抡答者的台位号，对抢答限时及回答问题限时设为倒计时，并有显示提示。系统的主要功能模块方框图如图1-6所示。
图1-6 系统主要功能模块
数字抢答器采用模块化设计，在抢答比赛中广泛应用，各组分别有一个抢答按钮。一共有8个按键输入，分别对应8路选手的抢答按键。
主持人有开始和结束键。在后台主持人可以修改，抢答时间和选手回答问题的时间设置，原始状态下抢答时间为30s，回答问题时间为30s。通过加键和减键修改上述时间，改完后结束键确定。新时间开始有效，主持人按键开始后，选手开始抢答为有效，数码显示屏显示抢答时间倒计时和选手号，在最后五秒扬声器发生提示。如果主持人没有按下开始键而选手就抢答视为犯规，数码显示屏显示犯规者的代号，扬声器持续发生。主持人可按键结束，新一轮抢答开始。
单片机是整个抢答器的核心，内部电路设计用汇编语言编写。它完成了时间参数的设定，抢按号码的译码，保存；显示；输出，抢按及答题倒计时功能等。数字抢答器设计中，有一个共阳的数码管组，四个数码管。其中两个显示时间，一个空位，一个显示抢答号码。主持人依次按下复位键，开始键后开始抢答。可以抢按：超时数码管显示“FFF”，当抢按超过规定时间或答题超过规定时间后数码管显示“FFF”。若有选手在规定时间内抢按成功，则可以答题，数码管显示抢答时间的同时也显示选手号码。若在按开始键前抢答表示违规，数码管显示“FF”并显示选手号码。
1．7 抢答器的工作流程
抢答器的基本工作原理：在抢答竞赛或呼叫时，有多个信号同时或不同时送入主电路中，抢答器内部的寄存器工作，并识别、记录第一个号码，同时内部的定时器开始工作，记录有关时间并产生超时信号。在整个抢答器工作过程中，显示电路、声音电路等还要根据现场的实际情况向外电路输出相应信号。抢答器的工作流程分为：系统复位、正常流程、违例流程等几部分，如图1-7所示：
图1-7 抢答器工作流程
2.硬件设计
2．1 硬件电路的设计原理
本系统采用AT89S51单片机作为核心，控制系统的四个模块分别为：单片机最小系统、显示模块、显示驱动模块、抢答开关模块。抢答器原理框图如图2-1所示。
图2-1 抢答器原理框图
2．2 硬件电路的设计
本设计分为硬件设计和软件设计，这两者相互结合，不可分离；从时间上看，硬件设计的绝大部分工作量是在最初阶段，到后期往往还要做一些修改。只要技术准备充分，硬件设计的大返工是比较少的，软件设计的任务贯彻始终，到中后期基本上都是软件设计任务，随着集成电路技术的飞速发展，各种功能很强的芯片不断出现，使硬件电路的集成度越来越高，硬件设计的工作量在整个项目中的所占的比重逐渐下降。为使硬件电路设计尽可能合理，应注意以下几方面：
(1) 尽可能采用功能强的芯片，以简化电路，功能强的芯片可以代替若干普通芯片，随着生产工艺的提高，新型芯片的的价格不断下降，并不一定比若干普通芯片价格的总和高。
(2) 留有设计余地。在设计硬件电路时，要考虑到将来修改扩展的方便。因为很少有一锤定音的电路设计，如果现在不留余地，将来可能要为一点小小的修改或扩展而被迫进行全面返工。
(3) 程序空间，选用片内程序空间足够大的单片机，本设计采用AT89S51单片机。
(4) RAM空间，AT89S51内部RAM不多，当要增强软件数据处理功能时，往往觉得不足。如果系统配置了外部RAM，则建议多留一些空间。如选用8155作I/O接口，就可以增强256字节RAM.如果有大批数据需要处理，则应配置足够的RAM，如6264，62256等。随着软件设计水平的提高，往往只要改变或增加软件中的数据处理算法，就可以使系统功能提高很多，而系统的硬件不必做任何更换就使系统升级换代。只要在硬件电路设计初期考虑到这一点，就应该为系统将来升级留足够的RAM空间，哪怕多设计一个RAM的插座，暂不插芯片也好。
(5) I/O端口：在样机研制出来后进行现场试用时，往往会发现一些被忽视的问题，而这些问题不是靠单纯的软件措施来解决的。如有些新的信号需要采集，就必须增加输入检测端；有些物理量需要控制，就必须增加输出端。如果在硬件电路设计就预留出一些I/O端口，虽然当时空着没用，那么用的时候就派上用场了。
系统总体原理图如下图2-2：
图2-2 系统原理图
图中U1为单片机AT89S51， S0-S7分别为8路抢答按键，分别接到单片机的P1.0-P1.7中。P3.0为开始抢答，P3.1为停止，数码管位选选P0口，数码管段选选P2口，扬声器输出为P3.6口。P3.4为时间加1调整，P3.5为时间减1调整。
2．3 最小系统
2．4 稳压电源电路设计
AT89S51的工作电压为+5V，±0.5V， 工作电流200mA
其它部分工作电流：
总电流：≤500mA
功耗：≤2.5W
电源电路见下图2-4，为典型电路这里不再叙述
2．5 时钟频率电路的设计
单片机必须在时钟的驱动下才能工作。在单片机内部有一个时钟振荡电路，只需要外接一个振荡源就能产生一定的时钟信号送到单片机内部的各个单元，决定单片机的工作速度。时钟电路如图2-5所示。
一般选用石英晶体振荡器。此电路在加电大约延迟10ms后振荡器起振，在XTAL2引脚产生幅度为3V左右的正弦波时钟信号，其振荡频率主要由石英晶振的频率确定。电路中两个电容 C1，C2的作用有两个：一是帮助振荡器起振；二是对振荡器的频率进行微调。C1，C2的典型值为30uF。
单片机在工作时，由内部振荡器产生或由外直接输入的送至内部控制逻辑单元的时钟信号的周期称为时钟周期。其大小是时钟信号频率的倒数，常用fosc表示。图中时钟频率为12MHz，即fosc=12MHz，则时钟周期为1/12µs。
2．6 复位电路的设计
单片机的第9脚RST为硬件复位端，只要将该端持续4个机器周期的高电平即可实现复位，复位后单片机的各状态都恢复到初始化状态，其电路图如图2-6所示：
图4-5中由按键S8以及电解电容C3、电阻R9构成按键及上电复位电路。由于单片机是高电平复位，所以当按键S8按下时候，单片机的9脚RESET管脚处于高电平，此时单片机处于复位状态。当上电后，由于电容的缓慢充电，单片机的9脚电压逐步由高向低转化，经过一段时间后，单片机的9脚处于稳定的低电平状态，此时单片机上电复位完毕，系统程序从0000H开始执行。
值得注意的是，在设计当中使用到了硬件复位和软件复位两种功能，由上面的硬件复位后的各状态可知寄存器及存储器的值都恢复到了初始值，而前面的功能介绍中提到了倒计时时间的记忆功能，该功能的实现的前提条件就是不能对单片机进行硬件复位，所以设定了软复位功能。软复位实际上就是当程序执行完毕之后，将程序指针通过一条跳转指令让它跳转到程序执行的起始地址。
2．7 显示电路的设计
显示功能与硬件关系极大，当硬件固定后，如何在不引起操作者误解的前提下提供尽可能丰富的信息，全靠软件来解决。
在这里我们使用的是七段数码管显示，通常在显示上我们采用的方法一般包括两种：一种是静态显示，一种是动态显示。其中静态显示的特点是显示稳定不闪烁，程序编写简单，但占用端口资源多；动态显示的特点是显示稳定性没静态好，程序编写复杂，但是相对静态显示而言占用端口资源少。在本设计中根据实际情况采用的是动态显示方法。
通过查表法，将其在数码管上显示出来，其中P0口为字型码输入端，P2口低位为字选段输入端。在这里我们通过查表将字型码送给7段数码管显示的数字，数码管显示原理如下：
图2-7中数码管采用的是4个七段共阳数码管，其中A-G段分别接到单片机的P2口，由单片机输出的P1口数据来决定段码值，位选码COM1、COM2、COM3、COM4分别接到单片机的P0.0、P0.1、P0.2、P0.3，由单片机来决定当前该显示的是哪一位。在图中还有四个4.7K的电阻，连接在P0口上，用作P0口的上拉电阻，保证P0口没有数据输出时候处于高电平状态。
2．8 键盘扫描电路的设计
键盘是人与单片机打交道的主要设备。关于键盘硬件电路的设计方法也可以在文献和书籍中找到，配合各种不同的硬件电路，这些书籍中一般也提供了相应的键盘扫描程序。站在系统监控软件设计的立场上来看，仅仅完成键盘扫描，读取当前时刻的键盘状态是不够的，还有不少问题需要妥善解决，否则，人们在操作键盘就容易引起误操作和操作失控现象。在单片机应用中键盘用得最多的形式是独立键盘及矩阵键盘。
它们各有自己的特点，其中独立键盘硬件电路简单，而且在程序设计上也不复杂，一般用在对硬件电路要求不高的简单电路中；矩阵键盘与独立键盘有很大区别，首先在硬件电路上它要比独立键盘复杂得多，而且在程序算法上比它要烦琐，但它在节省端口资源上有优势得多，因此它更适合于多按键电路。其次就是消除在按键过程中产生的“毛刺”
现象。这里采用最常用的方法，即延时重复扫描法，延时法的原理为：因为“毛刺”脉冲一般持续时间短，约为几ms，而我们按键的时间一般远远大于这个时间,所以当单片机检测到有按键动静后再延时一段时间(这里我们取10ms)后再判断此电平是否保持原状态,如果是则为有效按键，否则无效。
数字抢答器设计中采用了独立键盘的方式，本设计中有8个抢答按键输入，一个开始按键、一个结束按键，此外还有抢答时间调整键、回答时间调整键，加一按键、减一按键各一个。如图2-8所示。
在图2-8-1中8个抢答按键分别接入单片机的P1.0-P1.7端口，单片机通过读取P1.0-P1.7的值来判断当前输入的是8个抢答按键中的哪一个。抢答时间调整和回答时间调整接到单片机的P3.2和P3.3接口，加一及减一按键接到单片机的P3.4和P3.5接口。开始及结束按键接到单片机的41、42脚，这里用到了单片机41、42脚复合功能中的IO端口功能，单片机通过读取41、42脚的P3.0、P3.1的IO端口值来判断当前是否处于抢答开始状态或抢答结束状态。
按键开关输入需要解决的两个主要问题是判断是否有按键按下和消除按键抖动的影响。按键的确认反映在电压上，就是和按键相连的引脚呈现出高电平还是低电平。消除按键的抖动通常有硬件、软件两种消除方法。一般在按键较多时，采用软件的方法消除抖动，即在第一次检测到有按键按下时，执行一段延时12~15ms的子程序后，再确认该键电平是否任保持为闭合状态电平，如果保持为闭合状态电平就可以确认真有按键按下，从而消除抖动的影响。
一般电子装置中都设计有按键输入，用以控制程序执行时数据的输入或是特殊功能的设置及操作。在控制电路中，如果按键数不多是可以使用一个按键对应一条输入位线控制，即独立式按键。这种接法，一根输入线上的按键是否被按下，不会影响其他输入线上的工作状态。因此，通过检测输入线的电平状态就可以很容易判断哪个键按下了。独立式按键可以用单稳态锁存器消除抖动。
如果监控程序中的读键操作安排在主程序（后台程序）或键盘中断（外部中断）子程序中，则该延时子程序便可直接插入读键过程中。如果读键过程安排在定时中断子程序中，就可省去专门的延时子程序，利用两次定时中断的时间间隔来完成抖动处理。
2．9 发声电路的设计
我们知道，声音的频谱范围约在几十到几千赫兹，若能利用程序来控制单片机某个口线的“高”电平或低电平，则在该口线上就能产生一定频率的矩形波，接上喇叭（压电陶瓷型扬声器）就能发出一定频率的声音，若再利用延时程序控制“高”“低”电平的持续时间，就能改变输出频率，从而改变音调，使喇叭发出不同的声音。
数字抢答器设计如图2-9所示，单片机通过内部定时器的操作实现交替变换的波形输出驱动扬声器发声。
3．软件设计模块
3．1 主程序系统结构图
3．2 软件任务分析
软件任务分析和硬件电路设计结合进行，哪些功能由硬件完成，哪些任务由软件完成，在硬件电路设计基本定型后，也就基本上决定下来了。
软件任务分析环节是为软件设计做一个总体规划。从软件的功能来看可分为两大类：一类是执行软件，它能完成各种实质性的功能，如测量，计算，显示，打印，输出控制和通信等，另一类是监控软件，它是专门用来协调各执行模块和操作者的关系，在系统软件中充当组织调度角色的软件。这两类软件的设计方法各有特色，执行软件的设计偏重算法效率，与硬件关系密切，千变万化。
软件任务分析时，应将各执行模块一一列出，并为每一个执行模块进行功能定义和接口定义（输入输出定义）。在各执行模块进行定义时，将要牵扯到的数据结构和数据类型问题也一并规划好。
各执行模块规划好后，就可以监控程序了。首先根据系统功能和键盘设置选择一种最适合的监控程序结构。相对来讲，执行模块任务明确单纯，比较容易编程，而监控程序较易出问题。这如同当一名操作工人比较容易，而当一个厂长就比较难了。
软件任务分析的另一个内容是如何安排监控软件和各执行模块。整个系统软件可分为后台程序（背景程序）和前台程序。后台程序指主程序及其调用的子程序，这类程序对实时性要求不是太高，延误几十ms甚至几百ms也没关系，故通常将监控程序（键盘解释程序），显示程序和打印程序等与操作者打交道的程序放在后台程序中执行；而前台程序安排一些实时性要求较高的内容，如定时系统和外部中断（如掉电中断）。也可以将全部程序均安排在前台，后台程序为“使系统进入睡眠状态”，以利于系统节电和抗干扰。
3．3 程序流程图
在本设计中包括了以下主要的程序：主程序，查询程序，非法抢答程序，抢答时间调整程序，回答时间调整程序，倒计时程序，正常抢答处理程序，犯规处理程序，显示及发声程序。主流程图如5-2所示：
3．4 程序清单
OK EQU 20H;抢答开始标志位
RING EQU 22H;响铃标志位
ORG 0000H
AJMP MAIN
ORG 0003H
AJMP INT0 SUB
ORG 000BH
AJMP T0INT
ORG 0013H
AJMP INT1 SUB
ORG 001BH
AJMP T1 INT
ORG 0040H
MAIN: MOV R1,#30;初设抢答时间为30s
MOV R2,#60;初设答题时间为60s
MOV TMOD,#11H;设置未定时器/模式1
MOV TH0,#0F0H
MOV TL0,#0FFH;越高发声频率越高,越尖
MOV TH1,#3CH
MOV TL1,#0B0H;50ms为一次溢出中断
SETB EA
SETB ET0
SETB ET1
SETB EX0
SETB EX1;允许四个中断,T0/T1/INT0/INT1
CLR OK
CLR RING
SETB TR1
SETB TR0;一开始就运行定时器,以开始显示FFF.如果想重新计数,重置TH1/TL1就可以了
;=====查询程序=====
START: MOV R5,#0BH
MOV R4,#0BH
MOV R3,#0BH
ACALL DISPLAY;未开始抢答时候显示FFF
JB P3.0,NEXT;ddddddd
ACALL DELAY
JB P3.0,NEXT;去抖动,如果"开始键"按下就向下执行,否者跳到非法抢答查询
ACALL BARK;按键发声
MOV A,R1
MOV R6,A;送R1->R6,因为R1中保存了抢答时间
SETB OK;抢答标志位,用于COUNT只程序中判断是否查询抢答
MOV R7,#01H ;读抢答键数据信号标志，这里表示只读一次有用信号
MOV R3,#0AH;抢答只显示计时,灭号数
AJMP COUNT;进入倒计时程序,"查询有效抢答的程序"在COUNT里面
NEXT: JNB P1.0,FALSE1
JNB P1.1,FALSE2
JNB P1.2,FALSE3
JNB P1.3,FALSE4
JNB P1.4,FALSE5
JNB P1.5,FALSE6
JNB P1.6,FALSE7
JNB P1.7,FALSE8
AJMP START
;=====非法抢答处理程序=====
FALSE1: MOV R3,#01H
AJMP ERROR
FALSE2: MOV R3,#02H
AJMP ERROR
FALSE3: MOV R3,#03H
AJMP ERROR
FALSE4: MOV R3,#04H
AJMP ERROR
FALSE5: MOV R3,#05H
AJMP ERROR
FALSE6: MOV R3,#06H
AJMP ERROR
FALSE7: MOV R3,#07H
AJMP ERROR
FALSE8: MOV R3,#08H
AJMP ERROR
;=====INT0(抢答时间R1调整程序)=====
INT0SUB:MOV A,R1
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY;先在两个时间LED上显示R1
JNB P3.4,INC0;P3.4为+1s键,如按下跳到INCO
JNB P3.5,DEC0;P3.5为-1s键,如按下跳到DECO
JNB P3.1,BACK0;P3.1为确定键,如按下跳到BACKO
AJMP INT0SUB
INC0: MOV A,R1
CJNE A,#63H,ADD0;如果不是99,R2加1,如果加到99,R1就置0，重新加起。
MOV R1,#00H
ACALL DELAY1
AJMP INT0SUB
ADD0: INC R1
ACALL DELAY1
AJMP INT0SUB
DEC0: MOV A,R1
JZ SETR1;如果R1为0, R1就置99，
DEC R1
ACALL DELAY1
AJMP INT0SUB
SETR1: MOV R1,#63H
ACALL DELAY1
AJMP INT0SUB
BACK0: RETI
;=====INT1(回答时间R2调整程序)=====
INT1SUB:MOV A,R2
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY
JNB P3.4,INC1
JNB P3.5,DEC1
JNB P3.1,BACK1
AJMP INT1SUB
INC1: MOV A,R2
CJNE A,#63H,ADD1
MOV R2,#00H
ACALL DELAY1
AJMP INT1SUB
ADD1: INC R2
ACALL DELAY1
AJMP INT1SUB
DEC1: MOV A,R2
JZ SETR2
DEC R2
ACALL DELAY1
AJMP INT1SUB
SETR2: MOV R2,#63H
ACALL DELAY1
AJMP INT1SUB
BACK1: RETI
;=====倒计时程序(抢答倒计时和回答倒计时都跳到改程序)=====
REPEAT:MOV A,R2 ;使用锦囊时重新计时
MOV R6,A
CLR RING
COUNT: MOV R0,#00H;重置定时器中断次数
MOV TH1,#3CH
MOV TL1,#0B0H;重置定时器
RECOUNT:MOV A,R6;R6保存了倒计时的时间,之前先将抢答时间或回答时间给R6
MOV B,#0AH
DIV AB;除十分出个位/十位
MOV 30H,A;十位存于(30H)
MOV 31H,B;个位存于(31H)
MOV R5,30H;取十位
MOV R4,31H;取个位
MOV A,R6
SUBB A,#07H
JNC LARGER;大于5s跳到LARGER,小于等于5s会提醒
MOV A,R0
CJNE A,#0AH,FULL;1s中0.5s向下运行
CLR RING
AJMP CHECK
FULL: CJNE A,#14H,CHECK;下面是1s的情况,响并显示号数并清R0,重新计
SETB RING
MOV A,R6
JZ QUIT;计时完毕
MOV R0,#00H
DEC R6;一秒标志减1
AJMP CHECK
LARGER: MOV A,R0
CJNE A,#14H,CHECK;如果1s向下运行,否者跳到查"停/显示"
DEC R6;计时一秒R6自动减1
MOV R0,#00H
CHECK: JNB P3.1,QUIT;如按下停止键退出
JNB OK,CHECKK ;只在回答倒计时才有效
AJMP NEXTT
CHECKK:JNB P3.0,REPEAT ;判断是否使用锦囊
NEXTT: ACALL DISPLAY
JB OK,ACCOUT;如果是抢答倒计时,如是则查询抢答,否者跳过查询继续倒数(这里起到锁抢答作用)
AJMP RECOUNT
ACCOUT:
MOV A,36H
JNB ACC.0,TRUE1
JNB ACC.1,TRUE2
JNB ACC.2,TRUE3
JNB ACC.3,TRUE4
JNB ACC.4,TRUE5
JNB ACC.5,TRUE6
JNB ACC.6,TZ1
JNB ACC.7,TZ2
AJMP RECOUNT
TZ1:JMP TRUE7
TZ2:JMP TRUE8
QUIT: CLR OK;如果按下了"停止键"执行的程序
CLR RING
AJMP START
;=====正常抢答处理程序=====
TRUE1: ACALL BARK
MOV A,R2
MOV R6,A;抢答时间R2送R6
MOV R3,#01H
CLR OK;因为答题的计时不再查询抢答,所以就锁了抢答
AJMP COUNT
TRUE2:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#02H
CLR OK
AJMP COUNT
TRUE3:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#03H
CLR OK
AJMP COUNT
TRUE4:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#04H
CLR OK
AJMP COUNT
TRUE5:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#05H
CLR OK
AJMP COUNT
TRUE6: ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#06H
CLR OK
AJMP COUNT
TRUE7:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#07H
CLR OK
AJMP COUNT
TRUE8:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#08H
CLR OK
AJMP COUNT
;=====犯规抢答程序=====
ERROR: MOV R0,#00H
MOV TH1,#3CH
MOV TL1,#0B0H
MOV 34H,R3;犯规号数暂存与(34H)
HERE: MOV A,R0
CJNE A,#06H,FLASH;0.3s向下运行->灭并停响
CLR RING
MOV R3,#0AH
MOV R4,#0AH
MOV R5,#0AH;三灯全灭
AJMP CHECK1
FLASH: CJNE A,#0CH,CHECK1;下面是0.8s的情况,响并显示号数并清R0,重新计
SETB RING
MOV R0,#00H
MOV R3,34H;取回号数
MOV R5,#0BH
MOV R4,#0BH;显示FF和号数
AJMP CHECK1
CHECK1: JNB P3.1,QUIT1
ACALL DISPLAY
AJMP HERE
QUIT1: CLR RING
CLR OK
AJMP START
;=====显示程序=====
DISPLAY:MOV DPTR,#DAT1;查表显示程序,利用P0口做段选码口输出/P2低三位做位选码输出,
MOV A,R3
MOVC A,@A+DPTR
MOV P2,#0feH
MOV P0,A
ACALL DELAY2
MOV DPTR,#DAT2
MOV A,R5
MOVC A,@A+DPTR
MOV P2,#0fdH
MOV P0,A
ACALL DELAY2
MOV A,R4
MOVC A,@A+DPTR
MOV P2,#0fbH
MOV P0,A
ACALL DELAY2
RET
DAT1:DB 00h,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H
;"灭","1","2","3","4","5","6","7","8","9","灭","F"
DAT2:DB 3fh,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H
;第一个为零,其他与上相同,因为十位如果为零显示熄灭
;====加减时间延时(起到不会按下就加N个数)======
DELAY1: MOV 35H,#08H
LOOP0: ACALL DISPLAY
DJNZ 35H,LOOP0
RET
;=====延时4236个机器周期(去抖动用到)=====
DELAY: MOV 32H,#12H
LOOP: MOV 33H,#0AFH
LOOP1: DJNZ 33H,LOOP1
DJNZ 32H,LOOP
RET
;=====延时4236个机器周期(显示用到)=====
DELAY2: MOV 32H,#43H
LOOP3: MOV 33H,#1EH
MOV A,R7 ;每隔60~70个机器周期读一次P1口,全为1时为无效数据,继续读,有一个不为1时,转到正常抢答处理
JNZ AAAA1 ;没读到有效数据时继续转到AAAA1
LOOP2: DJNZ 33H,LOOP2
DJNZ 32H,LOOP3
RET
;=====读抢答按键数据口程序=====
;由于在读抢答数据口的时候，单片机首先进入倒计时程序，再调用显示程序，最后才检测按键口
;然而在检测按键口时动态扫描要调用三次(4ms)延时程序.这样就会导致读数据口出现滞后,造成1号优先最高.8号最低.
;故采用在延时子程序中加了读数据口程序.保证了灵敏度和可靠性
AAAA1: MOV A,P1
CJNE A,#0FFH,AA1 ;当不全为1时的数据为有效数据
AA0: MOV 36H,A ;将有效数据送到36H暂存
AJMP LOOP2
AA1: DEC R7
AJMP AA0
;=====发声程序=====
BARK: SETB RING
ACALL DELAY1
ACALL DELAY1
CLR RING;按键发声
RET
;=====TO溢出中断(响铃程序)=====
T0INT: MOV TH0,#0ECH
MOV TL0,#0FFH
JNB RING,OUT;
CPL P3.6;RING标志位为1时候P3.6口不断取反使喇叭发出一定频率的声音
OUT: RETI
;=====T1溢出中断(计时程序)=====
T1INT: MOV TH1,#3CH
MOV TL1,#0B0H
INC R0
RETI
END
4.总结
本设计以AT89S51单片机为核心，根据烧录其中的程序控制整个系统的工作流程。整体性好，人性化强、可靠性高，实现了数字显示控制的智能化，是各个需要显示数字或广告宣传的有力工具。通过该设计.我不仅加深了对单片机理论的理解，将理论很好地应用到实际当中去，而且我还学会了如何去培养我们的创新精神，从而不断地战胜自己，超越自己。创新，是要我们学会将理论很好地联系实际，并不断地去开动自己的大脑，从为人类造福的意愿出发，做自己力所能及的，别人却没想到的事。使之不断地战胜别人，超越前人。同时，更重要的是，我在这一设计过程中，学会了坚持不懈，不轻易言弃。设计过程，也好比是我们人类成长的历程，常有一些不如意，也许这就是在对我们提出了挑战，勇敢过，也战胜了，胜利的钟声也就一定会为我们而敲响。
当然，我的设计还存在着一些缺陷，有待于在将来设计中进一步提高，在此恳请老师批评指正。这次设计也让我懂得细节决定成败，在以后的设计中我会严格吸取教训，做的更好！
致谢
本课程设计是在我的指导老师刘卉老师的亲切关怀和细心指导下完成的，在设计过程中，自始至终凝聚着导师的心血。恩师那治学严谨的态度，渊博的学识感染着我。她那诲人不倦、宽厚朴实的作风给我们留下了不可磨灭的影响，是我学习的榜样，使我终生受益无穷。在此论文完成之际，特向恩师表达诚挚的谢意同时以最崇高的敬意。
除此之外，在课题进行当中，还得到了其他老师，教授等的细心指导和诸多帮助。他们的无私帮助和耐心指导也是我得以完成本课题的关键。再此我向他们表示由衷的感谢和深切的问候。此间我还得到了同学等诸多指导，再此表示感谢。
我还要感谢我的一些同学，他们在我最需要帮助的时候无私的伸出了援助之手，在此，对于他们无私的帮助我表示深深的感谢。可以说如果没有他们的帮助我就不可能顺利的按时完成毕业设计。
真诚的感谢所有的帮助过我的老师们，同学们、家人和朋友们。
参考文献
[1]王效华,张咏梅.单片机原理与应用.北京:北京交通大学出版社,2007.
[2]杨素行.模拟电子技术基础简明教程.三版.北京:高等教育出版社,2006.
[3]余孟尝.数字电子技术基础简明教程.3版.北京:高等教育出版社,2006.
[4]胡学海.单片机原理及应用系统设计[M].北京:电子工业出版社,2005.
[5]沈红卫.基于单片机的智能系统设计与实现[M].北京:电子工业出版社,2005.
[6]徐建军.MCS-51系列单片机应用及接口技术[M].北京:人民邮电出版社,2003.
[7]何利民.单片机应用技术大全.北京:北京航空航天大学出版社,1994.
附录一 元器件清单
附录二 系统原理图
